C_COSTCENTERCOMPANYCODEVH

CDS View

Cost Center Company Code Value Help

C_COSTCENTERCOMPANYCODEVH is a CDS View in S/4HANA. Cost Center Company Code Value Help. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_AllocCoCodeCtrlgAreaVH view from CONSUMPTION Company Code for Conrolling Area
P_CompanyCodeCOAreaVH view from CONSUMPTION 
@AbapCatalog.sqlViewName: 'CCOSTCTRCOCODEVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.semanticKey:  [ 'CompanyCode' ]
@ObjectModel.dataCategory: #VALUE_HELP
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@EndUserText.label: 'Cost Center Company Code Value Help'
@AccessControl.privilegedAssociations: ['_ControllingAreaText']
@Consumption.ranked: true
define view C_CostCenterCompanyCodeVH
  as select distinct from  I_CompanyCodeVH
  association [0..1] to I_ControllingArea as _ControllingAreaText on $projection.ControllingArea = _ControllingAreaText.ControllingArea

{

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.7
      }
  key CompanyCode,

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ControllingArea',
                     element: 'ControllingArea' }
        }]
      @ObjectModel.text.element: ['ControllingAreaName']
      @UI.textArrangement: #TEXT_LAST
      ControllingArea,
      @UI.hidden: true
      _ControllingAreaText.ControllingAreaName,
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.7
      }
      CompanyCodeName,
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.7
      }
      CityName,

      Country,
      @Semantics.currencyCode: true
      Currency,

      _Currency,
      @Consumption.hidden: true
      _ControllingAreaText

}
where ( ControllingArea <> '' or ControllingArea is not null )

Learn More